Fonction LEN

Longueur d’une chaîne de caractères VBA

La fonction VBA LEN permet de renvoyer le nombre de caractère d’un texte.

Len("Dophis")
'Cette commande renvoie 6

Fonction LEFT

Extraire le texte à gauche d’une chaîne de caractères VBA

La fonction VBA LEFT permet d’extraire les x caractères à gauche d’un texte de départ.

Left("Dophis",3)
'Cette commande renvoie Dop

Fonction RIGHT

Extraire des caractères à droite d’un texte VBA

La fonction VBA RIGHT permet d’extraire  les x caractères à droite d’un texte initial.

Right("Dophis",4)
'Cette commande renvoie phis

Fonction UCASE

Convertir en majuscule du texte en VBA

La fonction VBA UCASE permet de passer en majuscule un texte.

Ucase("Dophis")
'Cette commande renvoie DOPHIS

Fonction LCASE

Convertir en minuscule du texte en VBA

La fonction VBA LCASE permet de passer en minuscule un texte.

Lcase("Dophis")
'Cette commande renvoie dophis

Fonction MID

Extraire x caractères à l’intérieur d’un texte – VBA

La fonction VBA MID permet d’extraire un nombre de caractères déterminés à l’intérieur d’une chaîne de caractères.

Il faut transmettre 3 paramètres à cette fonction :

  • texte initial : par exemple “Dophis”
  • la position du premier caractère dans la chaîne. Par exemple pour commencer d’extraire à partir de p dans Dophis, la position est : 3
  • le nombre de caractères à extraire à partir de p. Prenons par exemple 2
Mid("Dophis",3,2)
'Cette commande renvoie ph

Fonction INSTR

Donner la position des caractères dans un texte – VBA

La fonction VBA InStr permet de renvoyer la position de caractères dans un texte.

3 arguments sont transmettre à cette fonction :

  • point de départ de la recherche : cet argument est optionnel. S’il n’est pas renseigné, la recherche commence au premier caractère
  • texte sur lequel porte la recherche. Par exemple : Dophis
  • les caractères recherchés dans la chaîne. Par exemple, nous souhaitons connaître le position de ph dans Dophis
Instr(1,"Dophis","ph")
'Cette commande renvoie 3
'Cette commande aurait pu être écrite Instr("Dophis","ph")

Cette fonction renvoie la première position trouvée. Si la chaîne de caractère que vous recherchez est présente plusieurs fois dans le texte de départ, la fonction ne renvoie que la première position.

Si le texte recherché n’est pas trouvé la fonction renvoie 0.

Fonction REPLACE

Remplacer des caractères par d’autres caractères – VBA

La fonction VBA Replace permet de remplacer des caractères par d’autres caractères.

3 arguments sont à transmettre à cette fonction :

  • texte de départ : “Dophis : développement et formation sur mesure Excel et Access”
  • texte à remplacer : Par exemple “Excel”
  • texte de remplacement
Replace("Dophis : développement et formation sur mesure Excel et Access","Excel","VBA")
'Cette commande renvoie "Dophis : développement et formation sur mesure VBA et Access"

Fonction SPLIT

Scinder une chaîne : identifier les mots séparés par un caractère spécifique

Cette fonction permet de récupérer dans un tableau l’ensemble des éléments d’une chaîne de caractères qui sont séparés par un élément à définir.

Par exemple, vous souhaitez récupérer l’ensemble des éléments séparés par ; de la chaîne suivante:

268069955055656;185065156106190;169091505522055;270071027803371;160116690501129

Function SpliterChaine(valeur As Variant, separateur As String) As Variant
Dim Tableau() As String
Dim i As Integer
SpliterChaine = Split(valeur, separateur)
End Function

Dans cet exemple le séparateur est un ; mais vous pouvez définir n’importe quel caractère comme séparateur.

Pour traiter la chaîne de caractère, vous réalisez ensuite une boucle sur la variable tableau que vous avez générée.

Sub TraitementChaine()
Dim i As Integer
Dim Var_traitement

Var_traitement = SpliterChaine("268069955055656;185065156106190;169091505522055;270071027803371;160116690501129", ";")
For i = LBound(Var_traitement) To UBound(Var_traitement)
    'Vous réalisez dans la boucle le traitement que vous souhaitez
    Debug.Print Var_traitement(i)
Next i
End Sub

Fonction StrReverse

Inverser l’ordre des lettres

Pour inverser l’ordre des lettres d’une chaîne de caractères, une fonction VBA permet de le faire : StrReverse.

StrReverse("1234")
'cette fonction renvoie 4321

Supprimer tous les accents

Cette fonction permet de remplacer tous les accents d’une chaîne de caractères par la même lettre sans accent.

Function SupprAccent(chaine As String)
Dim VarCtrl As String * 1
Dim VarRempl As String * 1
Dim i As Integer
Const Accent = "àáâãäåéêëèìíîïðòóôõöùúûüç"
Const SansAccent = "aaaaaaeeeeiiiioooooouuuuc"
For i = 1 To Len(Accent)
    VarCtrl = Mid(Accent, i, 1)
    VarRempl = Mid(SansAccent, i, 1)
    chaine = Replace(chaine, VarCtrl, VarRempl)
Next
SupprAccent = chaine
End Function

Remplacer les caractères interdits pour les noms de fichier

Lorsque vous créez des fichiers, certains caractères sont interdits dans le nom du fichier. Cette fonction permet de gérer ces caractères interdits. La fonction détecte les caractères interdits et les remplace par un caractère que vous définissez.

Function CaracteresInterdits(chaine As Variant, ListeCaracInterdit As String, new_caract As String) As Variant
'''''' Caractères interdits pour nom de fichier et répertoire :      "\/:*?""<>|;"
Dim i As Integer
Dim A As String
On Error GoTo erreur
If IsNull(chaine) Then
    CaracteresInterdits = Null
    Exit Function
End If

For i = 1 To Len(ListeCaracInterdit)
    A = Mid(ListeCaracInterdit, i, 1)
    chaine = Replace(chaine, A, new_caract)
Next

CaracteresInterdits = chaine
Exit Function
erreur:
CaracteresInterdits = chaine
End Function

Pour faire appel à cette fonction, vous pouvez utiliser la procédure VBA suivante :

Sub RemplacementCaractere()
Debug.Print CaracteresInterdits("nom \:du<fichier;erronne.xlsx", "\/*:?""<>|;", "_")
End Sub

Il est possible de changer le caractère de remplacement par rien en précisant “” pour le 3ème paramètre de la fonction.

Dernière position d’un caractère dans une chaîne de caractères

Pour identifier la dernière position d’un caractère dans une chaîne de caractère, il est possible d’utiliser la fonction suivante.

A titre d’exemple vous avez le chemin complet d’accès à un fichier : nom du répertoire \ nom du fichier. Vous souhaitez récupérer le nom du fichier. Pour cela il faut identifier le dernier antislash (\) de la chaîne.

Function DernierePosition(VarTexte As Variant, VarStrRecherche As String) As Integer
Dim position As Integer

position = InStr(1, StrReverse(VarTexte), VarStrRecherche)
If position = 0 Then
    DernierePosition = 0
Else
    DernierePosition = position
End If
End Function

Pour identifier l’antislash d’une chaîne de caractère, la fonction précédente va être mise en œuvre.

Function NomFichier(VarRepNom As String) As Variant
On Error GoTo erreur
Debug.Print DernierePosition(VarRepNom, "\")
NomFichier = Right(VarRepNom, DernierePosition(VarRepNom, "\") - 1)
Exit Function
erreur:
NomFichier = Null
End Function


Sub Exemple()
Debug.Print NomFichier("C:\Dophis\Exemple\NomFichier.xlsx")
'renvoie NomFichier.xlsx
End Sub

Supprimer les doublons dans une chaîne de caractères VBA

Vous souhaitez supprimer les doublons présents dans une chaine de caractères qui sont séparés par un élément distinctif et répétitif. Par exemple vous avez un texte avec des prénom en double : “Monique Marion Jean Lucien Monique Laura Evan Marion Evan“.

Public Function SuppDoublonChaine(valeur As Variant, separateur As String) As String
Dim nbEspaces As String
Dim i As Byte
Dim c
Dim VarDic
Dim Temp
    Temp = ""
    nbEspaces = (Len(valeur) - Len(Replace(valeur, separateur, ""))) / Len(separateur)
    Set VarDic = CreateObject("Scripting.Dictionary")
    If valeur <> "" Then
        For i = 0 To nbEspaces
            c = Split(valeur, separateur)(i)
            If Not VarDic.Exists(c) Then VarDic.Add c, c
        Next
        
        For Each d In VarDic.Items
            If Temp <> "" Then
                Temp = Temp & separateur & d
            Else
                Temp = d
            End If
        Next
    End If
    SuppDoublonChaine = Trim(Temp)
End Function

En utilisant cette fonction le résultat est le suivant : ” Monique Marion Jean Lucien Laura Evan”. Les doublons ont été supprimés.

Sub Test()
Debug.Print SuppDoublonChaine("Monique Marion Jean Lucien Monique Laura Evan Marion Evan", " ")
End Sub

Formation VBA pour manipuler les chaînes de caractères

Nous proposons des formations VBA sur mesure en visio ou en présentiel sur votre lieu de travail pour maîtriser l’utilisation des fonctions VBA chaîne de caractère.

La formation VBA peu vous permettre de matriser ces différentes fonctions.